wheel bend rate 50 range -12 -> +12
include gm.zel
include xg.zel
include patterns.zel
gmreset
1 xgreset
1 {reverbType,1,1}
:2 {varType,6,0}
:2 {varConnection,1}
restart
tempo=120
track [lead1 strings piano bass lead2 lead3 hits arps ]
track [bdrum snares toms hats cymbals claps revcymb dsetup perc ]
track lead [tg1 [lead1 lead3 ]]
lead1 $$1 pan=0
set lead1setup {
hbank=0
lbank=68
patch 98
variation=100
}
lead1setup
setPitchBendRange12
lead3 $$7 pan=127
lead1setup
setPitchBendRange12
RPNa=0 RPNb=1 data=55
lead !!=100 @@5
duration /
r5 ~AGA restart
set theme {
~FAEADAC^A a#2 A^2 ~GGFGEGDGC^Ga#G a^2 G^2 ~FFEFDFCFa#Fa^F g#2 F^2 ~EEDEC#Ea#Ea^Eg^E f4D eC#
~AGA }
[theme ]4~
set lead2setup {
hbank=0
lbank=6
patch 80
attack=80
}
lead1 lead2setup
lead3 lead2setup
lead
duration //
!!=120 A16 {modwheel,16,100} G16 {modwheel,16,100} 
G8 A#8 A^16 [12 bend 4=-12] {modwheel,16,100} W40
F^16 [ 14 bend 2=3] {modwheel,16,100} W0 G#16 {modwheel,16,120}
G^8 [6 bend 2=-2 ] {modwheel,8,100} W0 F^4 E4 D^8wC# W0
strings $$2 !!=100 @@5
hbank=0
lbank=3
patch 49
expression=127
volume=120
duration 4
|9 [a^D^F^ g^a#DF ga#C^E fa^CE f^a^a#D g#bDE g^a^C#E f/aD g^/a^C#E ]8~
bass $$3 !!=100 @@3
hbank=0
lbank=0
patch 39
setPitchBendRange12
set bass1 {
*2?1 ?1@+1 ?1@+1 }

duration //
volume=120
|24 10 a6 [ 1.5 bend 2=12 2.5=0 ] W0
|25 {bass1,d^,d,d,d,g,g,g,g,c^,c,c,c,f,f,f,f,a#@,a#@,a#@,a#@,b@,b@,b@,b@,c#,c,c,c,d^,d,e^,a^} 
[{bass1,d,d,d,d,g^,g,g,f,e,e,e,e,f,f,f,f,a#@,a@,a^@,a#@,b@,b@,b@,b@,c#,c#,c#,c#,d,d,e,a^} ]2~
piano $$4 !!=90 @@5
hbank=0
lbank=41
patch 2
release=0
chorus=64
variation=100
duration //
|17 [**/2 {chordgen3,aDF,g^a#DF,g^a#C^E,f^a^CE,f^a^a#D^,g#bDE,g^a^C#E} 
**1 f8aD e8g^a^C# ]3~

dsetup $$10
hbank=127
lbank=0
patch 0
reverb=127
{drumPitch,34,60,35,68,40,60,39,60,42,70,46,70,38,60,49,40}
{drumReverb,34,0}
claps $$10 !!=80 @@3
duration //
|17 [[r4 D#4 ]3~ R D# R2 D#4 ]16~
hats $$10 !!=70 @@3
duration //
|17 [[F# F# F#!+40 F# ]4~ ]8~ [[F# F# A# A#!1 ]4~ ]32~

bdrum $$10 !!=110 @@3
duration //
|24 8 !!-60 !! 8+60 [b ]8~
[[[b4 ]4~ ]7~ b4 b4 !!-60 !! 8+60 [b ]8~ ]4~

snares $$10 !!=80 @@3
duration //
|32 10 duration /6
!!-40 !! 3+40 [E ]3~ duration //
[E ]4~
[[r4 E2.5 E/!-20 E R E R2 E3 a# ]7~
!!-50 !! 8+50 [D ]8~ D3 D!-20 D2!-10 D2 ]2~
revcymb $$11 !!=90 @@5^
hbank=0
lbank=0
patch 119
attack=55
duration 1
|16 3 C
|24 3 C
arps $$5 !!=120 @@6
hbank=0
lbank=66
patch 80
variation=100
duration //
|33 [[~a^DFA ]4~ [~a#DFG^ ]4~ [~a#C^EG ]4~ [~a^C^EF ]4~
[~a#DFA^ ]4~ [~bDEG# ]4~ [~a^C#EG ]2~ ~f^aDF ~e^a^C#E 
~d^f^a^D^ ~f^a^D^F^ ~eaC#E ~c#eaC# ]2~
|41 portamento=127
porttime=20
cymbals $$10 !!=100 @@5
duration ///
|40 !!-60 !! 32+60 [c# ]32~
hits $$6 !!=120 @@6
hbank=0
lbank=64
patch 55
volume=127
duration 1
|41 dD !-20dD !-40 dD !-60dD
perc $$10 !!=120 @@5
duration //
|49 [r2 D# D# R2 E^ R R2 D# D# R2 E^ D^ ]16~
claps
duration 1
|57 [[r D# ]2~ ]8~
hats
duration //
|57 [[F# F# F#!+40 F# ]6~ F# A# F# F# A# F# F# F# ]4~
revcymb
duration 1
|56 3 C
|64 3 C
lead1 
|56 lead1setup
attack=64
lead3 lead1setup
attack=64
lead !!=100
duration /
|57 [theme ]2~
strings
duration 4
|65 expression 6=0
lead
|65 tempo 8=70
duration 2
|73 ~10faD ~10e^g^a^C# ~10d^2f^a^D^
