wheel bend rate 50 range -12 -> +12
include gm.zel
include xg.zel
include patterns.zel
gmreset
1 xgreset
{reverbType,1,1}
:2 {varType,6,0}
:2 {varConnection,1}
:2 {chorusType,42,0}
restart
tempo=120
track [chords1 chords2 bass bassh lead arps piano sfx hits ]
track [dsetup bdrum snares revcymb toms cymbals sticks claps hats ]
track chords [ chords1 chords2 ]
track st.chords [tg1 [chords1 chords2 ]]
track oct.bass [tg2 [bass bassh ]]
chords1 $$1 !!=90 @@5
hbank=0
lbank=64
patch 50
duration 1
d8 2 a6 2 D4 2 F2
pan=64 d16aDF [ 16=0 ]
chords2 $$2 !!=90 @@5
hbank=0
lbank=0
patch 51
pan=127
|3 expression=20 [16=127 ] D16FA
chords
duration 4
|7 set p1chords {
(daDF )(DFA )~ (caCE )(CEA )~ (a#@ga#D )(a#DG )~ (ca^CE )(CEA^ )~ }
[p1chords ]4~

bass $$3 !!=90 @@3
hbank=0
lbank=96
patch 38
filter=40
duration //
|7 set p1bass {
{octave4,D,D,D,D,C,C,C,C,a#,a,a,a,C,C,C,C} }
[p1bass ]4~


arps $$4 !!=100 @@6
hbank=0
lbank=69
patch 98
filter=50
|3 expression=20 [ duration 4
2=127 2=20 ] [[F E D a ]4~ ]4~
sfx $$5 !!=100 @@5
hbank=64
lbank=0
patch 5
duration 1
chorus=64
|6 3 C

revcymb !!=90 @@5 $$6
hbank=0
lbank=96
patch 119
duration /
|6 4 C2
|10 hbank=0
lbank=0
patch 119
6 C2
|14 6 C2
|18 6 C2
|22 6 C2
dsetup $$10
hbank=127
lbank=0
patch 0
{drumPitch,16,60,35,60,38,70,40,60,42,70,46,70}
reverb=100
snares $$10 !!=80 @@3
|6 6 E^

hats $$10 !!=70 @@3
duration //
|7 [[[F# F# A# F# ]4~ ]4~ ]4~
claps $$10 !!=90 @@2
duration 1
|7 [[r e^ r e^ ]4~ ]4~
cymbals $$10 !!=80 @@4
|11 C#
|15 C#
|19 C#
|23 C#
bdrum $$10 !!=100 @@3
duration //
|11 set bd1 {
[[b^4 ]7~ [b^3 b^!-20 ]~ ]2~ }
[bd1 ]3~
toms $$11 !!=110 @@4
hbank=127
lbank=0
patch 0
reverb=100
setPitchBendRange12
bend=-8
set fill {
duration //
!!-40 !! 2+40 [D^/ ]4~ [D^ ]4~ [C^ ]4~ [b ]4~ [f ]4~
}
|13 14 fill
|18 12 b a g f
|21 14 fill
snares
|14 !!-60 !! 16+60 [D^ ]16~
set sd1 {
[r4 D^4 r4 D^3 E R4 D^4 R4 D^3 D^!-20 ]2~ }
[sd1 ]2~

arps
set arpgen1 {
?1 ?2 ?1 ?2 ?1 ?3 ?1 ?2 }
|15 expression=127
set p1arps {
{arpgen1,D,a,F,D,a,F,C,a,E,C,a,E,a#,g,D,a,g,D,C,a^,E,C,a,E} }
[p1arps ]2~

|19 set p1arps2 {
{arp3,d^,f,a,D,c,e,a,C,a#@,d,g,a#,c,e,a^,C} }
p1arps2


lead $$7 !!=100 @@6
duration //
hbank=0
lbank=0
patch 73
variation=100
setPitchBendRange12
|22 12 c^/w0c#wd^wd#we^wf^wf#wg^wg# W0
|23 restart
st.chords
duration 4
aC#EA gaCEG f2aDF aC^D#F# aCD^F g^2a#DG
g#bDE a^/C^E g^/CE f#aCD^ ga#D^
g#bDE a^C#E a^C#EG^A# a^C#EGA^
bass
hbank=0
lbank=18
patch 38
filter=64
duration 4
setPitchBendRange12
a^ C# D^ D^ F# D^ g^ g^ g# a^/ C^// D#// D^ g^ g# a^w50C# W0 E^/ D^// C#//

arps
octave 5
{arp3,a^,C#,E^,A^,a^,C#,E,G^}
[{arp3,f^,a,D,F} ]2~
[{arp3,a^,C^,D^,F#} ]2~
[{arp3,g^,a#,D^,F^} ]2~
{arp3,g#,b,D^,E^,a,b,C^,E}
{arp3,f#,a,C,D^,g^,a^,a#,D^}
{arp3,g#,b,D^,E^,a^,b,C#,E^}
{arp3,C#,E^,G^,A#,C#,E,G,A^}
lead
duration //
{modwheel,8,100} a#6w0a^2 W0 {modwheel,14,100} a^14 a^wg^ W0 f^4we^ W0 e^6wg^2 W0 {modwheel,20,90} f^20 f^2wg^ W0
{modwheel,6,80} a#4wa^2 W0 a^4 a#4 {modwheel,6,70} C^8 D^wC^ W0 {modwheel,8,80} a#4wa^ {modwheel,8,90} a^6wC^2 W0 {modwheel,20,100} a#20 
f^/wg^wa^wa#wC^wD^wD#wE^ W0
{modwheel,10,90} F^10 E^4wb2 W0 {modwheel,16,90} D^4wC^12 W0 
{modwheel,10,80} C^4wD^6 W0 C^2wa#wa^ W0 {modwheel,16,90} a#16 
{modwheel,16,80} b12wC^2wD^ W0 {modwheel,16,80} E^12wF^4 W0
{modwheel,10,80} G^10 G^2wE^wC# W0 a^4wg^ W0 f^4we^ W0 
{modwheel,16,100} d^16
snares
|16 !!-40 !! 16+40 [D^ ]13~ D^/ D^/ [D^ ]2~

revcymb
duration 1
|16 3 C
toms
duration //
|15 14 fill
|17 restart
bass
hbank=0
lbank=0
patch 39
duration //
!!=100 [p1bass ]2~
chords
duration 4
[p1chords ]2~
bdrum
duration //
[bd1 ]2~

hats
[[[F# F# A# A#!1 ]4~ ]4~ ]2~

claps
duration 1
[[r e^ r e^ ]4~ ]2~
snares
duration //
[sd1 ]2~
revcymb
duration 1
|4 3 C
|8 3 C
cymbals
|5 C#
|9 C#
toms
duration //
|4 12 D C a f 
|7 14 fill

arps @@6
[p1arps ]2~
|5 p1arps2 
|9 restart
st.chords
duration 4
[aDFA aC#EA aC^FA gbDFG ]4~
bass @@2
bassh $$3 @@3
oct.bass
hbank=0
lbank=0
patch 39
volume=127
duration 4
!!=120
[D^ C# C^ b ]4~ 
hits $$8 !!=110 @@5
hbank=0
lbank=64
patch 55
variation=100
d^D^
|5 dD
|9 dD
|13 dD
arps
hbank=0
lbank=12
patch 39
filter=80
variation=100
octave 5
[{arp3,D^,E,F^,A^,C#,E,G^,A,C^,E,F,A,b,D,F,G} ]4~
hats
duration //
[[A#2!1 A#2 ]4~ ]8~
[[F# F# A# A#!1 ]4~ ]8~

claps
duration 1
[[r e^ r e^ ]4~ ]4~
bdrum
duration //
|5 [b^4 ]7~ b^3 b^!-20 
[b^2 ]8~ [b^ ]8~ !!-30 !! 8+30 [b^/ ]16~ 
[bd1 ]2~
toms
duration //
|4 12 b a g f
|7 14 fill
[r2 D3 C3 b3 a3 g f ]8~
snares
|8 12 E4
|8 !!-40 !! 16+40 [D^ ]16~
[sd1 ]2~
cymbals
|5 C#
|9 C#
|13 C#
revcymb
duration 1
|4 3 C
|8 hbank=0
lbank=96
patch 119
2 C2
|12 2 C2
lead @@5 !!=120
hbank=0
lbank=64
patch 84
filter=50
duration //
|5 {modwheel,14,100} F^14 Ew0F^ W0 {modwheel,14,100} G^14 F^wG^ W0 
{modwheel,8,80} A^8 C^2@ A^ C^2@ A^ C^2@ 
{modwheel,12,80} C^12@ [bend 4=2] W0
D^4@ [bend 4=-12] W0
sfx
duration 1
|8 2 c2
lead
|9 hbank=0
lbank=6
patch 81
volume=127
filter=64
chorus=100
duration //
!!=110 {modwheel,14,100} G^14 [bend 4=2] W0 A#wA^ W0 {modwheel,16,100} W0 G^16
{modwheel,14,100} F^14 EwF W0 {modwheel,16,100} G^16
portamento=127
porttime=20
octave 6 break on
[D^C#a#a^g^f^e^d^ ]2~
[E^D^C#a#a^g^f^e^ ]2~
[F^E^D^C#a#a^g^f^ ]2~
[G^F^E^D^C#a#a^g^ ]2~
bdrum
duration 1
[b ]4~
hats
duration //
[F# F# F#!+30 F# ]4~
toms
|17 10 !!-40 !! 2+40 [D/ ]4~ C b a g
snares
|17 12 !!-40 !! 4+40 [D ]4~ 
|18 restart
sfx !!=127
hbank=64
lbank=0
patch 114
duration 1
C4
st.chords
duration 4
break off
a#D^G^ a^C#EG^
duration 2
[d^f^a^D^ eaC#E faDF eaC#E^ ]10~
|18 expression=127 10=0
oct.bass
duration 2
a#2 C# a^ [/ bend /=5] W0
duration /
[D^15 a D^14 A2 [0.8 bend 1.2=-7] W0 ]2~
duration 1
[D^2 E^2 F^2 C#2 D^2 E^2 F^2 [1 bend 1=4] W0 A^2 [1 bend 1=-7] W0 ]3~
|18 duration 2
expression=127 10=0
piano $$9 !!=100 @@6
hbank=0
lbank=32
patch 2
variation=100
duration //
filter=30
|7 [ 16=64 16=30 ]8 [r2 [d3faD ]2~ [e3aC#E ]2~ e2aC#E
r2 f3aDF f3aDF e3gaC#E e3gaC#E e2gaC#E ]8~
|18 expression=127 80=0
bdrum
duration //
b16 b8 b4 
!!-40 !! 4+40 [b ]4~
[[b4 ]14~ !!-50 !! 8+50 [b ]8~ ]5~
|18 expression=127 80=0

hats
[[F# F# F#!+30 F# ]4~ ]14~
lead !!=110 @@5
hbank=0
lbank=6
patch 80
volume=100
filter=64
chorus=0
attack=64
release=100
portamento=0
duration 1
|11 **/4 [{octave3,D^,a,E,a,F,a,E^,a} ]2~

